https://github.com/sbdchd/luis

A Lua parser in Rust
https://github.com/sbdchd/luis

lua rust

Last synced: 9 months ago
JSON representation

A Lua parser in Rust

• Host: GitHub
• URL: https://github.com/sbdchd/luis
• Owner: sbdchd
• Created: 2018-09-23T02:16:07.000Z (over 7 years ago)
• Default Branch: master
• Last Pushed: 2019-03-11T02:08:05.000Z (almost 7 years ago)
• Last Synced: 2025-04-18T00:11:12.522Z (9 months ago)
• Topics: lua, rust
• Language: Rust
• Homepage:
• Size: 61.5 KB
• Stars: 4
• Watchers: 2
• Forks: 0
• Open Issues: 0
• Metadata Files:
  • Readme: README.md

Awesome Lists containing this project

README

          
# luis [![CircleCI](https://circleci.com/gh/sbdchd/luis.svg?style=svg)](https://circleci.com/gh/sbdchd/luis) [![cargo-badge](https://img.shields.io/crates/v/luis.svg)](https://crates.io/crates/luis)

> A Rust based Lua parser

## Why?

learning experience

## Prior art

- 

- 

from 

```

chunk ::= block

block ::= {stat} [retstat]

stat ::=  ‘;’ |

        varlist ‘=’ explist |

        functioncall |

        label |

        break |

        goto Name |

        do block end |

        while exp do block end |

        repeat block until exp |

        if exp then block {elseif exp then block} [else block] end |

        for Name ‘=’ exp ‘,’ exp [‘,’ exp] do block end |

        for namelist in explist do block end |

        function funcname funcbody |

        local function Name funcbody |

        local namelist [‘=’ explist]

retstat ::= return [explist] [‘;’]

label ::= ‘::’ Name ‘::’

funcname ::= Name {‘.’ Name} [‘:’ Name]

varlist ::= var {‘,’ var}

var ::=  Name | prefixexp ‘[’ exp ‘]’ | prefixexp ‘.’ Name

namelist ::= Name {‘,’ Name}

explist ::= exp {‘,’ exp}

exp ::=  nil | false | true | Numeral | LiteralString | ‘...’ | functiondef |

        prefixexp | tableconstructor | exp binop exp | unop exp

prefixexp ::= var | functioncall | ‘(’ exp ‘)’

functioncall ::=  prefixexp args | prefixexp ‘:’ Name args

args ::=  ‘(’ [explist] ‘)’ | tableconstructor | LiteralString

functiondef ::= function funcbody

funcbody ::= ‘(’ [parlist] ‘)’ block end

parlist ::= namelist [‘,’ ‘...’] | ‘...’

tableconstructor ::= ‘{’ [fieldlist] ‘}’

fieldlist ::= field {fieldsep field} [fieldsep]

field ::= ‘[’ exp ‘]’ ‘=’ exp | Name ‘=’ exp | exp

fieldsep ::= ‘,’ | ‘;’

binop ::=  ‘+’ | ‘-’ | ‘*’ | ‘/’ | ‘//’ | ‘^’ | ‘%’ |

        ‘&’ | ‘~’ | ‘|’ | ‘>>’ | ‘<<’ | ‘..’ |

        ‘<’ | ‘<=’ | ‘>’ | ‘>=’ | ‘==’ | ‘~=’ |

        and | or

unop ::= ‘-’ | not | ‘#’ | ‘~’

```